Désactiver l'activation de la barre de menu lorsque la touche Alt est enfoncée dans Windows 7

Cela fonctionne dans AHK v1.1.28+ :

~LAlt::Send {Blind}{vkE8}

J'étais à la recherche d'une solution au même problème : corriger la façon dont Windows réagit à "Alt+Shift" (changer la langue d'entrée), mais vous faites une erreur de frappe et appuyez sur Alt, suivi de Shift, sans chevauchement. Dans ce cas, Windows interprète l'unique Alt comme "sélectionner le menu", l'unique Shift ne fait rien, et tous les caractères que vous appuyez ensuite sélectionnent et entrent dans des menus aléatoires que vous n'aviez pas l'intention d'ouvrir.

Lorsque l'on utilise une application de chat comme Skype et que l'on parle une langue étrangère, il n'est pas rare de passer de l'un à l'autre avec Alt+Shift, et l'on peut faire beaucoup de choses stupides dans l'urgence.

@user3419297 m'a indiqué sa solution ici, que j'ai modifiée pour permettre à Alt+Shift de se produire dans tous les cas. Ce n'est qu'un #If de plus, mais un #If très important ! L'extrait pertinent :

; Disable stand-alone Alt key press: make Alt purely a modifier key.
; The If statement is required to get Alt+Shift work as expected. If it's not
; there, only [Press Alt], [Press Shift], [Release Shift], [Release Alt] would
; trigger the input language change. The other, more common sequence would be
; [Press Alt], [Press Shift], [Release  Alt], [Release Shift], but AutoHotKey
; would block it before it reaches Windows if the "#If" isn't there.
#If not GetKeyState("LShift", "P")
~LAlt::
    KeyWait, LAlt
return

; Make Alt+Something still work:
~LAlt Up::
    Send, {LAlt Up}
return

Mon script complet active également deux fonctionnalités Linuxiennes : Alt+F2 ouvre une "commande de lancement rapide", et l'appui sur l'Alt de droite réduit la fenêtre actuellement active :

;==============================================================================
; AutoHotKey script for "Linuxifying" Windows 8.
; Based on suggestions on SuperUser (http://superuser.com/questions/1147370)
; 
; Written by: Veselin Georgiev
; Date      : 2016-11-18
;==============================================================================

; Optional: Make Alt+F2 bring up the "quick launch command" Window.
; In this case, it simulates the Windows logo key press. On Windows 8, the
; cursor would be in the search bar, which nicely emulates launching a
; command.
!F2::
    Sleep 200
    Send {LWin}
return

; Disable stand-alone Alt key press: make Alt purely a modifier key.
; The If statement is required to get Alt+Shift work as expected. If it's not
; there, only [Press Alt], [Press Shift], [Release Shift], [Release Alt] would
; trigger the input language change. The other, more common sequence would be
; [Press Alt], [Press Shift], [Release  Alt], [Release Shift], but AutoHotKey
; would block it before it reaches Windows if the "#If" isn't there.
#If not GetKeyState("LShift", "P")
~LAlt::
    KeyWait, LAlt
return

; Make Alt+Something still work:
~LAlt Up::
    Send, {LAlt Up}
return

; Optional: Make the right alt key minimize the currently visible window.
~RAlt Up::WinMinimize A

Comme trouvé quelque part @MS

1. Appuyez sur Windows Key+ R, tapez Regedit et appuyez sur Entrée.
2. Naviguez vers HKEY_CURRENT_USER\Control Panel\Accessibility\Keyboard Preference
3. Maintenant, créez ou modifiez une valeur de chaîne (REG_SZ) appelée On et fixer sa valeur à 1
4. Déconnectez votre ordinateur pour qu'il prenne effet.

Je ne fais que poster une solution que j'ai trouvée dans le coin. Ça tue tout Alt Menu 100 %.

Alt::
KeyWait, Alt
return

LAlt Up::
if (A_PriorKey = "Alt")
    return
return

Si vous le préférez, vous pouvez également limiter cette solution à un seul programme :

#IfWinActive ahk_exe sublime_text.exe
    Alt::
    KeyWait, Alt
    return

    LAlt Up::
    if (A_PriorKey = "Alt")
        return
    return
#IfWinActive

1. https://www.autohotkey.com/boards/viewtopic.php?p=248473#p248473