Comment activer automatiquement Out of Office lorsque Outlook est fermé ?

Une autre façon de contourner ce problème (car je ne pense pas que vous puissiez modifier les paramètres de date et d'heure de l'assistant d'absence du bureau via VBA) consiste à effectuer les étapes suivantes :

1. Créez une règle dans "Règles et alertes" pour l'arrivée d'un message et faites en sorte que cette règle réponde automatiquement à tous les e-mails où vous figurez dans la partie "À" de l'e-mail.
2. Définissez la règle pour répondre en utilisant "demander au serveur de répondre en utilisant un message spécifique".
3. Remplissez le "message spécifique" avec un modèle de réponse standard (exemple approximatif : Cher client, je suis actuellement au bureau. Les heures de travail sont de 8h à 17h. Je vous répondrai rapidement à mon retour. Je vous prie d'agréer, <-insérer la signature->, mes salutations distinguées. )
4. Nommez la règle "HomeTime" (ou quelque chose de significatif - cela sera nécessaire pour le code vba ci-dessous).
5. Modifiez la sécurité de vos macros VBA dans Outlook pour permettre l'exécution des macros de manière appropriée.
6. Incluez le code suivant qui s'exécute pendant Application_Start y Application_Quit pour activer/désactiver la règle :

Option Explicit

Private Sub Application_Quit()
   SetRuleEnabled True
End Sub

Private Sub Application_Startup()
   SetRuleEnabled False
End Sub

Private Sub SetRuleEnabled(ByVal bEnable As Boolean)
   Dim oSession    As Outlook.NameSpace
   Dim oRule       As Outlook.Rule
   Dim oRules      As Outlook.Rules
   Dim oPA         As Outlook.PropertyAccessor

   Set oSession = Application.Session
   Set oRules = oSession.DefaultStore.GetRules()
   Set oPA = oSession.DefaultStore.PropertyAccessor

   '*** If the Out-Of-Office is already on (eg. holidays, sick leave etc.) 
   '*** then it might be best to force this rule permanently off
   If oPA.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x661D000B") Then
      bEnable = False
   End If

   For Each oRule In oRules
      If oRule.Name = "HomeTime" Then
         oRule.Enabled = bEnable
         oRules.Save
         Exit For
      End If
   Next

End Sub

Il faut garder à l'esprit que cette réponse sera déclenchée à chaque fois pour chaque réponse suivante. Contrairement à l'assistant Out-Of-Office qui ignore les réponses ultérieures.

PS. Avec la vérification d'Out of Office dans le VBA ci-dessus, vous aurez besoin d'une référence à la bibliothèque CDO. Si vous ne voulez pas vérifier si Out-Of-Office est activé, alors vous n'aurez pas besoin de CDO.

Génial ! Merci KCotreau. J'ai réussi à le faire fonctionner sur MS Outlook 2003. Voici l'extrait de code - je l'ai juste enveloppé dans le pré et le code pour ne pas tout avoir sur une seule ligne.

Private Sub Application_Quit() 
Dim objMAPISession As Object
Set objReminders = Nothing
If MsgBox("Would you like to turn the Out of Office Assistant on?", vbYesNo, "Activate Out of Office Assistant") = vbYes Then
    Set objMAPISession = CreateObject("MAPI.Session")
    objMAPISession.Logon , , True, False
    objMAPISession.OutOfOffice = True
    objMAPISession.Logoff
End If
Set objMAPISession = Nothing
End Sub

C'est bien, mais est-il possible de le faire fonctionner à une date/heure ultérieure ? Ce serait un vrai plus, car si vous avez prévu de partir en vacances et que vous oubliez d'activer le système OOF, il se déclenchera automatiquement sans intervention humaine... hein ?

Il semble qu'Outlook génère un événement Application_Quit lors de sa fermeture, qui pourrait être utilisé pour définir l'OOF. En appuyant sur Alt-F11 dans Outlook, l'éditeur de macro apparaît. Commencez à fouiller là-dedans.