curl capture le statut http et chronomètre la requête

Vous pouvez utiliser un fichier batch

@echo off
    setlocal enableextensions disabledelayedexpansion

    rem Just to test - Generate a file with URLs
    > ".\urls.txt" (
        echo http://superuser.com
        echo http://www.google.com
    )

    > ".\testResults.txt" (
        for /f "useback delims=" %%u in (".\urls.txt") do (
            set "statusCode="
            echo([%%u]
            for /f "tokens=1,2 delims=#" %%a in ('
                curl -w "##%%{time_connect}##." -I -s --url "%%~u"
                ^| findstr /l /b /c:"HTTP/" /c:"##"
            ') do if "%%b"=="." (
                setlocal enabledelayedexpansion
                echo(    !statusCode! - %%a
                endlocal
            ) else (
                set "statusCode=%%a"
            )
        )
    )

Juste deux boucles imbriquées. La première itère sur le fichier des URLs et la seconde exécute et traite la sortie de la fonction curl commandement.

La sortie de curl est filtrée avec findstr pour ne récupérer que les lignes contenant le code d'état et le temps de connexion (la chaîne de sortie dans le champ -w a été modifié pour localiser ces données dans la sortie)