Comment désactiver l'infobulle de survol sur les onglets ?

2019 quelqu'un (fonctionne sur Chrome et Chromium)

1. Allez à chrome://flags

2. Recherche pour "Hover" (survoler)

3. Définissez "Cartes de survol des onglets" sur "désactivé".

4. Redémarrer Chrome

Je n'ai pas pu obtenir le l'idée d'un programme déplaçant le curseur pour toi hors de mon esprit, donc j'en ai fait un ensemble.

Vous trouverez ci-dessous un script AutoHotkey (qui peut être compilé en un exécutable autonome si vous le souhaitez) qui détecte si le curseur de la souris est resté inactif près du haut d'une fenêtre Chrome pendant un certain temps et, si c'est le cas, le déplace vers le coin inférieur droit de l'écran.

Il fonctionne comme prévu et empêche les infobulles de s'afficher, mais en raison du décalage dans le temps (déclenchement du sous-programme et compte à rebours de l'infobulle), l'infobulle s'affiche parfois une fraction de seconde avant le déplacement du curseur. Ce phénomène peut être réduit en diminuant la durée du compte à rebours (l'option tip variable).

Je pense également à améliorer le script en gérant le timer manuellement au lieu d'utiliser le timer d'AutoHotkey. De cette façon, il peut compter à partir de la dernière fois que la souris a été déplacée ou que le bouton a été pressé, au lieu de compter à chaque fois que le bouton a été pressé. x secondes quoi qu'il en soit.

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;   MoveIdleMouse.ahk
;
; Prevents tooltips from being annoying in Chrome by detecting
; when the mouse is idle while near the top of a Chrome window
; and then moving it to the bottom-right corner of the screen.
;
; https://superuser.com/questions/393738/
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

#SingleInstance force
#Persistent

; Read the tooltip delay from the registry (this is the amount of time the
; cursor has to hover over something in order to trigger the tooltip)
RegRead, tip, HKCU, Control Panel\Mouse, MouseHoverTime

; Divide it by two to accommodate staggared timing. Adjust as desired.
;tip:=tip/2

; Set specified subroutine to run every so often (before tooltip triggered)
SetTimer, CheckCursor, %tip%

; Get the current mouse cursor position to compare to during first interval
MouseGetPos, x1, y1
return

; This subroutine checks the current cursor position and moves if idle
CheckCursor:
  ; First check if the cursor is over a Chrome window; ignore if not
  IfWinNotActive, ahk_class Chrome_WidgetWin_0
    return

  ; Next, check if any buttons are pressed and ignore if so
  if (GetKeyState("LButton") or GetKeyState("RButton") or GetKeyState("MButton")
      or GetKeyState("XButton1") or GetKeyState("XButton2"))
    return

  ; Get the current mouse position and check if it is both unchanged, and
  ; near the top of Chrome (position is relative to window by default)
  MouseGetPos, x2, y2
  If (((x1 = x2) and (y1 = y2))  and  ((y2 >= 0) and (y2 <= 27)))
  {
    ; Move the cursor to the bottom-right corner of the screen immediately
    ; You can adjust destination position as desired
    MouseMove, A_ScreenWidth+3, A_ScreenHeight+3, 0
  }
  else {
    ; Update current cursor position to compare to during the next interval
    x1 := x2
    y1 := y2
  }
  return