Comment ajouter une commande de mot de passe dans un fichier bat zip

Cela aurait été plus facile pour vous si le fichier batch avait été formaté correctement. La dernière ligne de ce fichier batch est responsable de l'exécution de 7z ligne de commande. C'est à ce moment que vous pouvez ajouter -p opción.

"%SevenZip%" a -pYourPassword -tzip "%DestZip%" -r "%BaseDir%\*.*"

J'ai également formaté le fichier

@echo off 
setlocal enabledelayedexpansion

REM Define file and folder locations 
set BaseDir=D:\SourceTest 
set DestZip=D:\Destinationtest\BACKUP.zip 
set SevenZip=C:\Program Files\7-Zip\7z.exe

REM Zip all files and folders echo Getting time ... 
for /f "tokens=1-9" %%a in ('wmic.exe Path Win32_LocalTime Get Day^,DayOfWeek^,Hour^,Minute^,Month^,Quarter^,Second^,WeekInMonth^,Year ^| find /v ""') do (
    set /a Line += 1
    if "!Line!"=="1" (
        set VarA=%%a&set VarB=%%b&set VarC=%%c&set VarD=%%d&set VarE=%%e&set VarF=%%f&set VarG=%%g&set VarH=%%h&set VarI=%%i
    ) 
    if "!Line!"=="2" (
        set !VarA!=%%a&set !VarB!=%%b&set !VarC!=%%c&set !VarD!=%%d&set !VarE!=%%e&set !VarF!=%%f&set !VarG!=%%g&set !VarH!=%%h&set !VarI!=%%i
    ) 
)
for %%a in (Month Day Hour Minute Second) do (
    if !%%a! LSS 10 set %%a=0!%%a!
) 
set TimeStamp=%Year%%Month%%Day%_%Hour%%Minute%%Second%
echo Compressing '%BaseDir%' ... 
for %%a in ("%DestZip%") do (
    set DestZip=%%~dpna-%TimeStamp%%%~xa
) 
"%SevenZip%" a -pPassword@1 -tzip "%DestZip%" -r "%BaseDir%\*.*"

Lorsque j'essaie d'extraire le fichier de sortie, il demande un mot de passe :

Pour crypter le nom du fichier, vous devez ajouter -mhe=on pour crypter l'en-tête du fichier. Mais cette option ne fonctionne pas avec zip format. Pour que cela fonctionne pour 7z effectuez les modifications suivantes :

changer le nom du fichier cible

set DestZip=D:\Destinationtest\BACKUP.7z

Modifier la dernière ligne

"%SevenZip%" a -mhe=on -pYourPassword "%DestZip%" -r "%BaseDir%\*.*"

Après ces changements, il demandera un mot de passe à chaque fois.