Comment "Répondre à tous" et conserver la pièce jointe originale dans Outlook ?

Apparemment pas sans un peu de code VBA. Voici quelque chose que j'ai trouvé qui prétend faire exactement cela. ( Source : )

Description : Cet exemple VBA d'Outlook crée et affiche une réponse au message actuellement ouvert ou sélectionné, y compris les pièces jointes dans l'original.

Sub ReplyWithAttachments()
    Dim rpl As Outlook.MailItem
    Dim itm As Object

    Set itm = GetCurrentItem()
    If Not itm Is Nothing Then
        Set rpl = itm.Reply
        CopyAttachments itm, rpl
        rpl.Display
    End If

    Set rpl = Nothing
    Set itm = Nothing
End Sub

Function GetCurrentItem() As Object
    Dim objApp As Outlook.Application

    Set objApp = Application
    On Error Resume Next
    Select Case TypeName(objApp.ActiveWindow)
        Case "Explorer"
            Set GetCurrentItem = objApp.ActiveExplorer.Selection.Item(1)
        Case "Inspector"
            Set GetCurrentItem = objApp.ActiveInspector.CurrentItem
    End Select

    Set objApp = Nothing
End Function

Sub CopyAttachments(objSourceItem, objTargetItem)
   Set fso = CreateObject("Scripting.FileSystemObject")
   Set fldTemp = fso.GetSpecialFolder(2) ' TemporaryFolder
   strPath = fldTemp.Path & "\"
   For Each objAtt In objSourceItem.Attachments
      strFile = strPath & objAtt.FileName
      objAtt.SaveAsFile strFile
      objTargetItem.Attachments.Add strFile, , , objAtt.DisplayName
      fso.DeleteFile strFile
   Next

   Set fldTemp = Nothing
   Set fso = Nothing
End Sub

Notes sur le code :

1. Utilise le GetCurrentItem() fonction pour revenir à l'élément actuellement sélectionné ou affiché.

2. Utilise le CopyAttachments() procédure pour copier les pièces jointes dans la réponse.

3. Remplacer itm.Reply をもって itm.ReplyAll si vous préférez répondre à tous.

(Oh, et j'ai trouvé ceci en 30 secondes environ en faisant une recherche sur le web pour "répondre à tous avec pièces jointes dans outlook").