C'est drôle, j'ai utilisé les 3 réponses jusqu'à présent ;)
Voici une autre option : utiliser applescript. Vous pouvez créer des applescripts qui ouvrent une fenêtre dans le répertoire courant du finder par exemple.
J'ai plusieurs applescripts de ce type et je les ai liés à des raccourcis clavier avec Quicksilver (ou Butler).
par défaut, j'utilise un raccourci clavier qui ouvre un terminal dans le répertoire courant de finder, mais seulement si finder est l'application principale. Sinon, j'obtiens simplement une nouvelle fenêtre. J'ai aussi des scripts qui ouvrent des sessions ssh vers certains serveurs et se reconnectent à une session écran. Avec l'option -x de screen, on peut avoir plusieurs erminal Windows qui regardent le même terminal de serveur, super :)
EDIT :
Voici le script que j'ai écrit et qui ouvre une nouvelle fenêtre, allant dans le répertoire courant du Finder si le Finder est l'application active :
on run
-- Figure out if we want to do the cd (doIt)
-- Figure out what the path is and quote it (myPath)
try
tell application "Finder" to set doIt to frontmost
set myPath to finder_path()
if myPath is equal to "" then
set doIt to false
else
set myPath to quote_for_bash(myPath)
end if
on error
set doIt to false
end try
-- Figure out if we need to open a window
-- If Terminal was not running, one will be opened automatically
tell application "System Events" to set isRunning to (exists process "Terminal")
tell application "Terminal"
-- Open a new window
if isRunning then do script ""
activate
-- cd to the path
if doIt then
-- We need to delay, terminal ignores the second do script otherwise
delay 0.3
do script "cd " & myPath in front window
end if
end tell
end run
on finder_path()
try
tell application "Finder" to set the source_folder to (folder of the front window) as alias
set thePath to (POSIX path of the source_folder as string)
on error -- no open folder windows
set thePath to ""
end try
return thePath
end finder_path
-- This simply quotes all occurrences of ' and puts the whole thing between 's
on quote_for_bash(theString)
set oldDelims to AppleScript's text item delimiters
set AppleScript's text item delimiters to "'"
set the parsedList to every text item of theString
set AppleScript's text item delimiters to "'\\''"
set theString to the parsedList as string
set AppleScript's text item delimiters to oldDelims
return "'" & theString & "'"
end quote_for_bash
Pour l'utiliser, ouvrez l'éditeur script et collez-le. Sauvegardez-le ensuite dans un endroit pratique (j'utilise ~/Library/script) et demandez à QuickSilver, Butler ou Google Quick Search Bar de l'exécuter. Avec QS et Butler, vous pouvez également définir des touches de raccourci globales.
J'espère que cela vous aidera,
Wout.
