J'ai longtemps été confronté à ce même problème. Moi aussi, je me perds dans des fichiers Excel denses lorsque j'utilise plusieurs écrans.

Il y a une énorme collection de plugins Excel disponibles sur internet. J'ai découvert que l'extension Excel de Kutools (la version gratuite) dispose d'une croix de surbrillance activée/désactivée en un seul clic qui reste visible même si Excel n'est pas mis au point. Kutools semble également disposer de nombreuses fonctionnalités supplémentaires, mais ce n'est certainement pas la seule option disponible.

Voici une capture d'écran du réticule de mise en évidence de Kutools en action :

Je sais que certaines personnes ont peur des plugins ou outils tiers, mais les utiliser est probablement l'option la plus rapide et la plus facile.

Insérer une zone de texte qui s'étend sur la longueur des cellules. Tapez une rangée de ******* caractères similaires pour remplir la zone de texte. Vous pouvez déplacer la zone de texte vers le bas de la page comme vous le feriez avec une règle ou une feuille de papier sur une copie papier. Supprimez le texte lorsque vous avez terminé.

Une solution simple _{qui place une couleur de cellule lorsque la sélection change}

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Selection.Interior.ColorIndex = xlColorIndexNone
    Selection.Interior.Color = RGB(204, 204, 204)
End Sub

Une solution complexe _{qui ne change la couleur de la cellule que lorsque le focus est perdu}

Dans un module standard :

Option Explicit    
Public s As Range

Dans la (les) feuille(s) dans laquelle (lesquelles) vous voulez qu'il travaille :

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Set s = Selection
End Sub

En ThisWorkbook :

Private Sub Workbook_Deactivate()
    If s Is Nothing Then
        Set s = Selection
        Exit Sub
    End If
    s.Interior.ColorIndex = xlColorIndexNone
    s.Interior.Color = RGB(204, 204, 204)

    ' This is optional formatting to make the cells look more like they're actually selected
    s.Borders.Color = RGB(130, 130, 130)
    s.BorderAround _
    Color:=RGB(30, 130, 37), Weight:=xlThick
End Sub

Private Sub Workbook_Activate()
    If s Is Nothing Then
        Set s = Selection
        Exit Sub
    End If
    s.Interior.ColorIndex = xlColorIndexNone
    s.Borders.ColorIndex = xlColorIndexNone
End Sub

_{Citations : La solution simple est basée sur <a href="https://superuser.com/a/746997/232563">une réponse </a>par <a href="https://superuser.com/users/146314/dave">@Dave </a>La solution complexe a été élaborée à partir de nombreuses sources, en particulier avec l'aide de la Commission européenne. <a href="https://stackoverflow.com/users/4996248/john-coleman">@JohnColeman </a>en <a href="https://stackoverflow.com/questions/41153872/how-to-send-variables-between-a-sheet-and-book">ce poste </a>.}

La mise en forme conditionnelle et VBA constituent un moyen très simple d'y parvenir.

Il suffit d'ajouter ceci à votre code ThisWorkbook :

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
    If Application.CutCopyMode = False Then
        Application.Calculate
    End If
End Sub

et exécuter le code suivant une seule fois pour créer les règles de formatage conditionnel :

Sub CreateConditionalFormats()
  Dim y As FormatCondition
    For Each ws In ThisWorkbook.Worksheets
        DoEvents

        'Optionally delete any existing conditional formats
        'ws.Cells.FormatConditions.Delete

        ' Selection highlight
        Set y = ws.Cells.FormatConditions.Add(Type:=xlExpression, Formula1:="=AND(ROW()=CELL(""row""), COLUMN()=CELL(""col""))")
        With y.Borders(xlTop)
            .LineStyle = xlSolid
            .Color = -16776961
            .TintAndShade = 0
            .Weight = xlThin
        End With
        With y.Borders(xlBottom)
            .LineStyle = xlSolid
            .Color = -16776961
            .TintAndShade = 0
            .Weight = xlThin
        End With
        With y.Borders(xlLeft)
            .LineStyle = xlSolid
            .Color = -16776961
            .TintAndShade = 0
            .Weight = xlThin
        End With
        With y.Borders(xlRight)
            .LineStyle = xlSolid
            .Color = -16776961
            .TintAndShade = 0
            .Weight = xlThin
        End With
        y.StopIfTrue = False
        y.SetFirstPriority

        ' Row highlight
        Set y = ws.Cells.FormatConditions.Add(Type:=xlExpression, Formula1:="=ROW()=CELL(""row"")")
        With y.Borders(xlTop)
            .LineStyle = xlDash
            .Color = -16776961
            .TintAndShade = 0
            .Weight = xlThin
        End With
        With y.Borders(xlBottom)
            .LineStyle = xlDash
            .Color = -16776961
            .TintAndShade = 0
            .Weight = xlThin
        End With
        y.StopIfTrue = False

        ' Column highlight
        Set y = ws.Cells.FormatConditions.Add(Type:=xlExpression, Formula1:="=COLUMN()=CELL(""col"")")
        With y.Borders(xlLeft)
            .LineStyle = xlDash
            .Color = -16776961
            .TintAndShade = 0
            .Weight = xlThin
        End With
        With y.Borders(xlRight)
            .LineStyle = xlDash
            .Color = -16776961
            .TintAndShade = 0
            .Weight = xlThin
        End With
        y.StopIfTrue = False
    Next
End Sub

L'utilisation de l'insertion d'une forme ou d'un rectangle est une solution simple. Sélectionnez l'option "Pas de remplissage" et vous pourrez même modifier les cellules à travers elle.

Jetez un coup d'œil à l'image ici :