Comment puis-je lancer automatiquement des applications après avoir monté un conteneur TrueCrypt ?

Je sais que cette question est ancienne, mais elle figure en bonne place dans les listes de recherche, alors j'ai pensé poster ma solution.

Je monte le disque et lance mes programmes à l'aide d'un fichier .bat. Je lance le fichier .bat dans les tâches planifiées "à l'ouverture de session".

Voici ma batte. Profitez-en.

Note, vous devez configurer truecrypt pour ne pas monter automatiquement vos "favoris" et il y a une situation que le bat suivant ne gère pas : Quand un volume est monté sur une lettre de lecteur différente de celle spécifiée.

REM - Truecrypt mount and launch file - 2013
REM - Set variables as needed below
@ECHO OFF

SET tcexec="%PROGRAMFILES%\truecrypt\truecrypt.exe"
SET mountdrive=x
SET volumefolder="%USERPROFILE%\truecrypt"
SET volumename=TrueCrypt-Volume

IF EXIST %mountdrive%: goto DriveExists

IF NOT EXIST %volumefolder%\%volumename% goto NoVolume

IF NOT EXIST %tcexec% goto noTC

REM Mount volume
cd %volumefolder%
%tcexec% /v %volumename% /l%mountdrive% /a /q
echo %ERRORLEVEL%
if ERRORLEVEL 1 GOTO mountfail
if ERRORLEVEL 0 GOTO startprograms

:startprograms
REM ******************************
REM ** Start your programs here **
REM ******************************
REM start "" "C:\Users\<userid>\AppData\Roaming\AeroFSExec\aerofs.exe"
REM start "" "C:\Program Files\ownCloud\owncloud.exe"

REM ********************************
REM ** END of Program Start block **
REM ********************************

goto end

:mountfail
echo Truecrypt failed to mount volume.
goto end

:noTC
echo Cant find truecrypt at: %tcexec%
goto end

:NoVolume
echo Identified volume does not exist: %volumefolder%\%volumename%
goto end

:DriveExists
echo Drive letter %mountdrive% already exists, cannot mount truecrypt volume
goto end

:End

Microsoft a un utilitaire (alias "PowerToy") pour Windows appelé TweakUI qui vous permet d'activer ou de désactiver la lecture automatique sur vos lecteurs (sous Poste de travail | Lecture automatique | Lecteurs dans le volet gauche du programme TweakUI). Je viens de monter un volume TrueCrypt et il est visible dans TweakUI - il semble donc que je puisse activer la lecture automatique). Désolé, je ne peux pas le tester davantage car je n'ai pas de fichier autorun.inf avec lequel jouer).

Dans un fichier .bat, vous pouvez appeler un autre fichier .bat aussi simplement que (voir la ligne qui commence par CALL) :

Le fichier MyBat1.bat contient ce texte :

@ECHO OFF

ECHO Here i will do things, like mount the .tc file

REM Here would go the command to mount the .tc file as drive letter X:

ECHO I am going to call to another bat script

CALL X:\MyBatFile_InsideTheTC.bat

ECHO I can do more things after thet other script runs

X:\MyBatFile_InsideTheTC.bat has this text:

@ECHO OFF

START "WhatEverTitleYouWant" "X:\MyDirectAccess.lnk"

... et ainsi de suite ...

X:\MyDirectAccess.lnk est un fichier créé par Windows lorsque vous créez un raccourci vers un programme, il peut également s'agir de n'importe quelle commande comme le démarrage de services, etc... j'ai donné l'exemple d'un .lnk car ce .lnk peut être configuré (dans les propriétés) pour être exécuté avec des privilèges élevés, il demande donc à l'utilisateur cette élévation, et c'est un moyen très facile de lancer des services après le montage d'un volume tc.

Ceci est également valable pour VeraCrypt (successeur de TrueCrypt qui utilise le code source de TrueCrypt).

Exemple : Avoir le dossier de données (htdoc) du serveur Web (Apache) à l'intérieur du fichier .tc (.hc pour VeraCrypt), le service Apache doit être configuré pour un démarrage manuel, et seulement après avoir monté le fichier .tc le service peut être démarré par [net star "Apache24"].

Cette configuration est pour Apache non portable, puisque Apache portable n'a pas de service et commence par une commande, mais donne une bonne idée de ce qui peut être fait à haut niveau.