Excel : Lien à double sens pour les cellules dans des classeurs distincts

J'ai testé cette méthode et je pense qu'elle devrait suffire à vous aider. Mais voici quelques points que j'ai remarqués.

La première chose à noter est que le Intersect ne fonctionne pas si vous comparez des plages dans différentes feuilles de calcul par cette question . Vous ne l'avez pas fait explicitement ici, mais je pense qu'il est judicieux de préciser avec quelle(s) feuille(s) de calcul vous travaillez au lieu de permettre à VBA de décider implicitement pour vous.

Deuxièmement, cette ligne est un exemple :

Workbooks("Test excel workbook 1 - macro.xlsm").Sheets(1).Range(Target.Address).Value = Target

Je trouve personnellement qu'il est bizarre de définir la valeur d'une plage comme étant une autre plage au lieu de la définir comme étant le valeur de l'autre plage, qui ressemblerait plutôt à ceci :

Workbooks("Test excel workbook 1 - macro.xlsm").Sheets(1).Range(Target.Address).Value = Target.Value

Voici le code que j'ai trouvé :

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    Const filePath As String = "C:\some\file\path\otherthing.xlsm"
    Dim otherwb As Workbook
    Dim otherws As Worksheet
    Dim thisws As Worksheet
    Dim rangeIntersection As Range

    'this will allow opening the other workbook without
    'displaying the white UI
    Application.ScreenUpdating = False

    'setting a reference to this worksheet
    Set thisws = ThisWorkbook.Worksheets("Sheet1")
    'opens an unopened workbook or it will simply set a reference
    'to this workbook if it's already opened
    Set otherwb = Excel.Workbooks.Open(filePath)
    'just chose a random worksheet
    Set otherws = otherwb.Worksheets(1)
    'doing the intersection
    Set rangeIntersection = _
        Application.Intersect(Range(Target.Address), _
        thisws.Range("A2:D5"))

    If Not rangeIntersection Is Nothing Then
        Application.EnableEvents = False
        otherws.Range(Target.Address).Value = Target.Value
        Application.EnableEvents = True
    End If

    'uncomment this if you do want to close the wb at the end
'    otherwb.Save
'    otherwb.Close
    Application.ScreenUpdating = True
End Sub

J'espère que cela vous aidera