Salut les gars, j'ai un serveur WSUS qui fonctionne bien avec Active Directory. Mais comment puis-je connecter des PC en groupe de travail exécutant Windows XP à WSUS sans les joindre à AD? Merci d'avance.
Réponses
Trop de publicités?
Coding Gorilla
Points
1928
Vous pouvez apporter les mêmes modifications nécessaires en mettant à jour le registre directement; une recherche rapide m'a conduit vers ce lien qui semble contenir les informations correctes. Sinon, une recherche un peu plus approfondie de votre part vous permettra probablement de trouver les informations qui vous manquent.
J'utilise le script batch suivant pour basculer les systèmes sur et hors de WSUS. Il fonctionne très bien pour mettre à jour rapidement les systèmes formatés avant de les donner.
Changez [SERVEUR] avec votre serveur WSUS sous la section :USEWSUS.
@echo off
:START
cls
echo Script WSUS temporaire
echo ==============================
echo Ce script va alterner entre l'utilisation du serveur WSUS interne et des serveurs de Microsoft.
echo.
set /p WSUSSETTING=Entrez [W] pour utiliser WSUS ou [C] pour effacer le réglage et utiliser les serveurs MS:
IF /i (%WSUSSETTING%) == (W) goto CONTINUE
if /i (%WSUSSETTING%) == (C) goto CONTINUE
echo.
echo Erreur : Sélection invalide
pause
goto START
:CONTINUE
echo Arrêt des services de mises à jour...
net stop wuauserv
echo Suppression des entrées de registre de temporisation (Sûr d'ignorer les erreurs)...
reg delete "HKLM\Software\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update" /v LastWaitTimeout /f
reg delete "HKLM\Software\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update" /v DetectionStartTime /f
reg delete "HKLM\Software\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update" /v NextDetectionTime /f
IF /i (%WSUSSETTING%) == (W) goto USEWSUS
IF /i (%WSUSSETTING%) == (C) goto USEMS
:USEWSUS
echo Modification du serveur de mises à jour vers le serveur WSUS local...
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate" /v WUServer /t REG_SZ /d "http://[SERVEUR]:8530" /f
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate" /v WUStatusServer /t REG_SZ /d "http://[SERVEUR]:8530" /f
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate\AU" /v NoAutoUpdate /t REG_DWORD /d 0 /f
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate\AU" /v AUOptions /t REG_DWORD /d 3 /f
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate\AU" /v AutoInstallMinorUpdate /t REG_DWORD /d 1 /f
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate\AU" /v UseWUServer /t REG_DWORD /d 1 /f
goto COMPLETE
:USEMS
echo Effacer le serveur de mises à jour WSUS...
reg delete "HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate" /v WUServer /f
reg delete "HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate" /v WUStatusServer /f
reg delete "HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate\AU" /v UseWUServer /f
goto COMPLETE
:COMPLETE
echo Démarrage des services de mises à jour...
net start wuauserv
:END
echo ---
echo Terminé.
pause
Kasius
Points
371
