Comment recharger votre fichier .vimrc sans redémarrer vim ?

Encore mieux, vous configurez Vim pour qu'il surveille les changements dans votre .vimrc et recharger automatiquement la configuration.

augroup myvimrc
    au!
    au BufWritePost .vimrc,_vimrc,vimrc,.gvimrc,_gvimrc,gvimrc so $MYVIMRC | if has('gui_running') | so $MYGVIMRC | endif
augroup END

Source : cette réponse sur SO

Remarque : cette méthode particulière tient compte des nombreuses variations des noms de fichiers de configuration de Vim, de sorte qu'elle est compatible avec Vim GUI, Vim Windows, etc.

Correspondance des clés

" Quickly edit/reload this configuration file
nnoremap gev :e $MYVIMRC<CR>
nnoremap gsv :so $MYVIMRC<CR>

Une solution entièrement automatisée

A automatiquement recharger lors de l'enregistrement, ajoutez ce qui suit à votre fichier $MYVIMRC :

if has ('autocmd') " Remain compatible with earlier versions
 augroup vimrc     " Source vim configuration upon save
    autocmd! BufWritePost $MYVIMRC source % | echom "Reloaded " . $MYVIMRC | redraw
    autocmd! BufWritePost $MYGVIMRC if has('gui_running') | so % | echom "Reloaded " . $MYGVIMRC | endif | redraw
  augroup END
endif " has autocmd

puis, pour la dernière fois, tapez :

:so %

La prochaine fois que vous enregistrez votre vimrc il sera automatiquement rechargé.

Caractéristiques :

• Indique à l'utilisateur ce qui s'est passé (également l'enregistrement à :messages )
• Gère les différents noms des fichiers de configuration
• Assurez-vous qu'il ne correspondra qu'au fichier de configuration réel (ignorez les copies dans d'autres répertoires, ou une fugitive:// diff)
• Ne générera pas d'erreur si vous utilisez vim-tiny

Bien sûr, le rechargement automatique ne se produira que si vous modifiez votre vimrc dans vim.

Une alternative à la mémorisation/dactylographie :so $MYVIMRC est ces mappings. Il vous permet d'éditer rapidement vimrc ( ev ) ou la source vimrc ( sv ).

" Quickly open/reload vim
nnoremap <leader>ev :split $MYVIMRC<CR>  
nnoremap <leader>sv :source $MYVIMRC<CR>

J'ai une version légèrement différente de ReloadVimrcFunction

" Reloads vimrc after saving it but keep cursor position
if !exists('*ReloadVimrcFunction')
    function! ReloadVimrcFunction()
        let save_cursor = getcurpos()
        source $MYVIMRC | windo redraw
        call setpos('.', save_cursor)
        echom "Reloaded $MYVIMRC"
    endfunction
endif
noremap <silent> <Leader>v :drop $MYVIMRC<cr>
command! -nargs=0 ReloadVimrc :call ReloadVimrcFunction()
nnoremap <silent> <C-s> :call ReloadVimrcFunction()<CR>

Afin d'éviter de charger la fonction deux fois, nous mettons :

if !exists('*ReloadVimrcFunction')

Nous sauvegardons également la position du curseur, car il serait ennuyeux de voir la position du curseur changer à chaque fois que nous rechargeons le système. $MYVIMRC .

J'ai également un augroup pour déclencher cette fonction chaque fois que je sauvegarde $MYVIMRC

augroup Reload
    autocmd!
    autocmd BufWritePost $MYVIMRC call ReloadVimrcFunction()
augroup END