J'ai rencontré ce problème également.
La réponse acceptée ne répondait pas à mes besoins. Je voulais connaître la taille de toutes les corbeilles de recyclage ainsi que leur total.
En utilisant le fournisseur WMI, il est facile d'accomplir cela : (enregistrez en tant que fichier .vbs)
dim oFS, oFolder, tailleTotaleFichier
Dim objWMIService, objItem, colItems, colPartitions, objPartition, _
objLogicalDisk, colLogicalDisks
Dim strComputer, strMessage, strPartInfo,strDeviceID,ret
set oFS = WScript.CreateObject("Scripting.FileSystemObject")
Set oShell = CreateObject( "WScript.Shell" )
strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_DiskDrive")
For Each objItem in colItems
strDeviceID = Replace(objItem.DeviceID, "\", "\\")
Set colPartitions = objWMIService.ExecQuery _
("ASSOCIATORS OF {Win32_DiskDrive.DeviceID=""" & strDeviceID & _
"""} WHERE AssocClass = Win32_DiskDriveToDiskPartition")
For Each objPartition In colPartitions
Set colLogicalDisks = objWMIService.ExecQuery _
("ASSOCIATORS OF {Win32_DiskPartition.DeviceID=""" & _
objPartition.DeviceID & _
"""} WHERE AssocClass = Win32_LogicalDiskToPartition")
strPartInfo = strPartInfo & "Disk Partition: " & objPartition.DeviceID
For Each objLogicalDisk In colLogicalDisks
strPartInfo = strPartInfo & " " & objLogicalDisk.DeviceID
ret = ret & objLogicalDisk.DeviceID & "\"
if oFS.FolderExists(objLogicalDisk.DeviceID&"\$Recycle.Bin") then
RECpath=oShell.ExpandEnvironmentStrings( _
objLogicalDisk.DeviceID & "\$Recycle.Bin")
set oFolder = oFS.GetFolder(RECpath)
ShowFolderDetails(oFolder)
else
ret = ret & " -empty- " & vbCr
end if
Next
strPartInfo = strPartInfo & vbCr
Next
Next
Wscript.Echo ret & "---------" & vbCr & "Total: " & calcSize(tailleTotaleFichier)
WSCript.Quit
Sub ShowFolderDetails(oF)
Dim size
tailleTotaleFichier = tailleTotaleFichier + oF.Size
size = calcSize(oF.Size)
ret = ret & " = " & size & vbCr
end Sub
function calcSize(tailleEnB)
Dim fSize, iKB, iMB, iGB, d
iKB = 1024
iMB = iKB * 1024
iGB = iMB * 1024
d = 2
if tailleEnB >= iGB then
fSize = round(tailleEnB/iGB,d) & " GB"
elseif tailleEnB >= iMB then
fSize = round(tailleEnB/iMB,d) & " MB"
elseif tailleEnB >= iKB then
fSize = round(tailleEnB/iKB,d) & " KB"
else
fSize = tailleEnB & " B"
end if
calcSize = fSize
end function
éditer : J'ai mis à jour le script pour qu'il ne plante pas si la partition n'a pas de corbeille de recyclage. Les octets sont désormais affichés correctement.
